OsmAnd/OsmAnd-api/build.gradle

apply plugin: 'com.android.library'
apply plugin: 'ivy-publish'
apply plugin: 'com.github.dcendents.android-maven'


android {
    compileSdkVersion 28
    buildToolsVersion "28.0.3"

    defaultConfig {
        minSdkVersion 14
        targetSdkVersion 26
        versionCode 2
        versionName "2.0"
    }
    lintOptions {
        abortOnError false
    }
    sourceSets {
        main {
            manifest.srcFile "AndroidManifest.xml"
            aidl.srcDirs = ["src"]
            java.srcDirs = ["src"]
        }
    }
}

afterEvaluate {
    publishing {
        publications {
             release(IvyPublication) {
                // Applies the component for the release build variant.
                from components.release
                organisation = 'net.osmand'
                module = 'android-aidl-lib'
                revision = 'master-snapshot'
             }
             debug(IvyPublication) {
                // Applies the component for the release build variant.
                from components.debug
                organisation = 'net.osmand'
                module = 'android-aidl-lib'
                revision = 'master-snapshot'
             }
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation 'com.android.support:support-annotations:28.0.0'
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from android.sourceSets.main.java.srcDirs
}

artifacts {
    archives sourcesJar
}